; $VER: Startup-Sequence 45.4 (4.4.2001)
; Startup-Sequence for AmigaOS 3.9

; The following lines disable updating "scsi.device" for driver
; software where this could lead to failures. They also start
; IDEFix if installed.
;
; You can manually disable updating "scsi.device" by setting
; the environment variable "NOSCSIUPDATE" to something.

If EXISTS C:SquirrelSCSI
    C:SquirrelSCSI
EndIf

Set SCSIUpdate 1
If EXISTS C:IDEFix
    C:IDEFix
    Set SCSIUpdate 0
EndIf
If EXISTS SYS:Expansion/XSurfIDE
    Set SCSIUpdate 0
EndIf
If EXISTS SYS:Prefs/Env-Archive/NOSCSIUPDATE
    Set SCSIUpdate 0
EndIf
If $SCSIUpdate EQ 1
    SetPatch QUIET
Else
    SetPatch SKIPROMUPDATES "scsi.device" QUIET
EndIf
Unset SCSIUpdate

C:Version >NIL:
C:AddBuffers >NIL: DF0: 15
FailAt 21

C:MakeDir RAM:T RAM:Clipboards RAM:ENV RAM:ENV/Sys
C:Copy >NIL: ENVARC: RAM:ENV ALL NOREQ

Resident >NIL: C:Assign PURE
Resident >NIL: C:Execute PURE
Resident >NIL: C:SetEnv PURE REPLACE

Assign >NIL: ENV: RAM:ENV
Assign >NIL: T: RAM:T
Assign >NIL: CLIPS: RAM:Clipboards
Assign >NIL: REXX: S:
Assign >NIL: PRINTERS: DEVS:Printers
Assign >NIL: KEYMAPS: DEVS:Keymaps
Assign >NIL: LOCALE: SYS:Locale
Assign >NIL: LIBS: SYS:Classes ADD
Assign >NIL: HELP: LOCALE:Help DEFER

BindDrivers
C:Mount >NIL: DEVS:DOSDrivers/~(#?.info)

C:LoadMonDrvs

SetEnv Language "english"
SetEnv Workbench $Workbench
SetEnv Kickstart $Kickstart
UnSet Workbench
UnSet Kickstart

C:AddDataTypes REFRESH QUIET
C:IPrefs
C:ConClip

Path >NIL: RAM: C: SYS:Utilities SYS:Rexxc SYS:C SYS:System S: SYS:Prefs SYS:WBStartup SYS:Tools SYS:Tools/Commodities



IF EXISTS S:User-Startup
  Execute S:User-Startup
EndIF

Resident Execute REMOVE
Resident Assign REMOVE

C:LoadWB
EndCLI >NIL:
